{
  description = "Producer and consumer in rust using rabbitmq";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.rust-analyzer-src.follows = "";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, crane, fenix, flake-utils, advisory-db, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        inherit (pkgs) lib;

        craneLib = crane.mkLib pkgs;
        src = craneLib.cleanCargoSource ./.;

        # Common arguments can be set here to avoid repeating them later
        commonArgs = {
          inherit src;
          strictDeps = true;

          buildInputs = with pkgs; [
            openssl
            pkg-config
            libiconv
            curl # for utoipa
          ] ++ lib.optionals pkgs.stdenv.isDarwin [
            # Additional darwin specific inputs can be set here
            pkgs.libiconv
          ];
          nativeBuildInputs = with pkgs;[
            openssl
            pkg-config
            libiconv
            curl # for utoipa
            makeWrapper
          ];

        };

        craneLibLLvmTools = craneLib.overrideToolchain
          (fenix.packages.${system}.complete.withComponents [
            "cargo"
            "llvm-tools"
            "rustc"
          ]);

        # Build *just* the cargo dependencies (of the entire workspace),
        # so we can reuse all of that work (e.g. via cachix) when running in CI
        # It is *highly* recommended to use something like cargo-hakari to avoid
        # cache misses when building individual top-level-crates
        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        individualCrateArgs = commonArgs // {
          inherit cargoArtifacts;
          inherit (craneLib.crateNameFromCargoToml { inherit src; }) version;
          # NB: we disable tests since we'll run them all via cargo-nextest
          doCheck = false;
        };

        fileSetForCrate = crate: lib.fileset.toSource {
          root = ./.;
          fileset = lib.fileset.unions [
            ./Cargo.toml
            ./Cargo.lock
            ./producer
            ./consumer
            ./common
            crate
          ];
        };

        # Build the top-level crates of the workspace as individual derivations.
        # This allows consumers to only depend on (and build) only what they need.
        # Though it is possible to build the entire workspace as a single derivation,
        # so this is left up to you on how to organize things
        producer = craneLib.buildPackage (individualCrateArgs // {
          pname = "producer";
          cargoExtraArgs = "-p producer";
          src = fileSetForCrate ./producer;
        });
        consumer = craneLib.buildPackage (individualCrateArgs // {
          pname = "consumer";
          cargoExtraArgs = "-p consumer";
          src = fileSetForCrate ./consumer;
        });
      in
      {
        checks = {
          # Build the crates as part of `nix flake check` for convenience
          inherit producer consumer;

          # Run clippy (and deny all warnings) on the workspace source,
          # again, reusing the dependency artifacts from above.
          #
          # Note that this is done as a separate derivation so that
          # we can block the CI if there are issues here, but not
          # prevent downstream consumers from building our crate by itself.
          producer-consumer-clippy = craneLib.cargoClippy (commonArgs // {
            inherit cargoArtifacts;
            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
          });

          producer-consumer-doc = craneLib.cargoDoc (commonArgs // {
            inherit cargoArtifacts;
          });

          # Check formatting
          producer-consumer-fmt = craneLib.cargoFmt {
            inherit src;
          };

          # Audit dependencies
          producer-consumer-audit = craneLib.cargoAudit {
            inherit src advisory-db;
          };

          # Audit licenses
          producer-consumer-deny = craneLib.cargoDeny {
            inherit src;
          };

          # Run tests with cargo-nextest
          # Consider setting `doCheck = false` on other crate derivations
          # if you do not want the tests to run twice
          producer-consumer-nextest = craneLib.cargoNextest (commonArgs // {
            inherit cargoArtifacts;
            partitions = 1;
            partitionType = "count";
          });

          # Ensure that cargo-hakari is up to date
          producer-consumer-hakari = craneLib.mkCargoDerivation {
            inherit src;
            pname = "producer-consumer-hakari";
            cargoArtifacts = null;
            doInstallCargoArtifacts = false;

            buildPhaseCargoCommand = ''
              cargo hakari generate --diff  # workspace-hack Cargo.toml is up-to-date
              cargo hakari manage-deps --dry-run  # all workspace crates depend on workspace-hack
              cargo hakari verify
            '';

            nativeBuildInputs = [
              pkgs.cargo-hakari
            ];
          };
        };

        packages = {
          inherit consumer producer;
          producer-container = pkgs.dockerTools.buildLayeredImage {
            name = "producer";
            tag = "latest";
            contents = with pkgs; [
              cacert
              openssl
              pkg-config
              libiconv
            ];

            config = {
              WorkingDir = "/app";
              Volumes = { "/app" = { }; };
              Entrypoint = [ "${producer}/bin/producer" ];
            };
          };

          consumer-container = pkgs.dockerTools.buildLayeredImage {
            name = "consumer";
            tag = "latest";
            contents = with pkgs; [
              cacert
              openssl
              pkg-config
              libiconv
            ];

            config = {
              WorkingDir = "/app";
              Volumes = { "/app" = { }; };
              Entrypoint = [ "${consumer}/bin/consumer" ];
            };
          };

        } // lib.optionalAttrs (!pkgs.stdenv.isDarwin) {
          producer-consumer-llvm-coverage = craneLibLLvmTools.cargoLlvmCov (commonArgs // {
            inherit cargoArtifacts;
          });
        };

        apps = {
          producer = flake-utils.lib.mkApp {
            drv = producer;
          };
          consumer = flake-utils.lib.mkApp {
            drv = consumer;
          };
        };

        devShells.default = craneLib.devShell {
          # Inherit inputs from checks.
          checks = self.checks.${system};
          LIBCLANG_PATH = "${pkgs.llvmPackages_17.libclang.lib}/lib";
          RUST_SRC_PATH = "${pkgs.rust.packages.stable.rustPlatform.rustLibSrc}";
          packages = with pkgs; [
            openssl
            pkg-config
            libiconv
            cargo-hakari
            cargo-nextest # testing
          ];
        };
      });
}