From b31019d64f9ddd1a869fa8fdb371c32c7ed9b578 Mon Sep 17 00:00:00 2001
From: tschai-yim <89387771+tschai-yim@users.noreply.github.com>
Date: Wed, 20 Mar 2024 08:41:18 +0100
Subject: [PATCH] qt: add adwaita platform theme

Fixes #4702 and https://github.com/NixOS/nixpkgs/issues/295345.
---
 modules/misc/qt.nix                           | 160 ++++++++++++------
 tests/modules/misc/qt/qt-basic.nix            |   2 -
 .../misc/qt/qt-platform-theme-gnome.nix       |   3 +-
 .../modules/misc/qt/qt-platform-theme-gtk.nix |   4 +-
 .../misc/qt/qt-platform-theme-gtk3.nix        |   4 +-
 5 files changed, 109 insertions(+), 64 deletions(-)

diff --git a/modules/misc/qt.nix b/modules/misc/qt.nix
index f02bc186..e3e5be41 100644
--- a/modules/misc/qt.nix
+++ b/modules/misc/qt.nix
@@ -6,6 +6,7 @@ let
   # Map platform names to their packages.
   platformPackages = with pkgs; {
     gnome = [ qgnomeplatform qgnomeplatform-qt6 ];
+    adwaita = [ qadwaitadecorations qadwaitadecorations-qt6 ];
     gtk = [ libsForQt5.qtstyleplugins qt6Packages.qt6gtk2 ];
     kde = [ libsForQt5.plasma-integration libsForQt5.systemsettings ];
     lxqt = [ lxqt.lxqt-qtplugin lxqt.lxqt-config ];
@@ -55,56 +56,85 @@ in {
     qt = {
       enable = lib.mkEnableOption "Qt 5 and 6 configuration";
 
-      platformTheme = lib.mkOption {
+      platformTheme = let
+        newOption = {
+          name = lib.mkOption {
+            type = with lib.types; nullOr str;
+            default = null;
+            example = "adwaita";
+            relatedPackages = [
+              "qgnomeplatform"
+              "qgnomeplatform-qt6"
+              "qadwaitadecorations"
+              "qadwaitadecorations-qt6"
+              [ "libsForQt5" "plasma-integration" ]
+              [ "libsForQt5" "qt5ct" ]
+              [ "libsForQt5" "qtstyleplugins" ]
+              [ "libsForQt5" "systemsettings" ]
+              [ "lxqt" "lxqt-config" ]
+              [ "lxqt" "lxqt-qtplugin" ]
+              [ "qt6Packages" "qt6ct" ]
+              [ "qt6Packages" "qt6gtk2" ]
+            ];
+            description = ''
+              Platform theme to use for Qt applications.
+
+              Some examples are
+
+              `gtk`
+              : Use GTK theme with
+                [`qtstyleplugins`](https://github.com/qt/qtstyleplugins)
+
+              `gtk3`
+              : Use [GTK3 integration](https://github.com/qt/qtbase/tree/dev/src/plugins/platformthemes/gtk3)
+                for file picker dialogs, font and theme configuration
+
+              `adwaita`
+              : Use Adwaita theme with
+                [`qadwaitadecorations`](https://github.com/FedoraQt/QGnomePlatform)
+
+              `gnome` (deprecated)
+              : Use GNOME theme with
+                [`qgnomeplatform`](https://github.com/FedoraQt/QGnomePlatform).
+                Is no longer maintained so prefer `adwaita`.
+
+              `lxqt`
+              : Use LXQt theme style set using the
+                [`lxqt-config-appearance`](https://github.com/lxqt/lxqt-config)
+                application
+
+              `qtct`
+              : Use Qt style set using
+                [`qt5ct`](https://github.com/desktop-app/qt5ct)
+                and [`qt6ct`](https://github.com/trialuser02/qt6ct)
+                applications
+
+              `kde`
+              : Use Qt settings from Plasma
+            '';
+          };
+          package = lib.mkOption {
+            type = with lib.types; nullOr (either package (listOf package));
+            default = null;
+            example =
+              lib.literalExpression "[pkgs.adwaita-qt pkgs.adwaita-qt6]";
+            description = ''
+              Theme package to be used in Qt5/Qt6 applications.
+              Auto-detected from {option}`qt.platformTheme.name` if possible.
+              See its documentation for available options.
+            '';
+          };
+        };
+      in lib.mkOption {
         type = with lib.types;
-          nullOr (enum [ "gtk" "gtk3" "gnome" "lxqt" "qtct" "kde" ]);
+          nullOr
+          (either (enum [ "gtk" "gtk3" "gnome" "adwaita" "lxqt" "qtct" "kde" ])
+            (lib.types.submodule { options = newOption; }));
         default = null;
-        example = "gnome";
-        relatedPackages = [
-          "qgnomeplatform"
-          "qgnomeplatform-qt6"
-          [ "libsForQt5" "plasma-integration" ]
-          [ "libsForQt5" "qt5ct" ]
-          [ "libsForQt5" "qtstyleplugins" ]
-          [ "libsForQt5" "systemsettings" ]
-          [ "lxqt" "lxqt-config" ]
-          [ "lxqt" "lxqt-qtplugin" ]
-          [ "qt6Packages" "qt6ct" ]
-          [ "qt6Packages" "qt6gtk2" ]
-        ];
         description = ''
-          Platform theme to use for Qt applications.
-
-          The options are
-
-          `gtk`
-          : Use GTK theme with
-            [`qtstyleplugins`](https://github.com/qt/qtstyleplugins)
-
-          `gtk3`
-          : Use [GTK3 integration](https://github.com/qt/qtbase/tree/dev/src/plugins/platformthemes/gtk3)
-            for file picker dialogs, font and theme configuration
-
-          `gnome`
-          : Use GNOME theme with
-            [`qgnomeplatform`](https://github.com/FedoraQt/QGnomePlatform)
-
-          `lxqt`
-          : Use LXQt theme style set using the
-            [`lxqt-config-appearance`](https://github.com/lxqt/lxqt-config)
-            application
-
-          `qtct`
-          : Use Qt style set using
-            [`qt5ct`](https://github.com/desktop-app/qt5ct)
-            and [`qt6ct`](https://github.com/trialuser02/qt6ct)
-            applications
-
-          `kde`
-          : Use Qt settings from Plasma
+          Deprecated. Use {option}`qt.platformTheme.name` instead.
         '';
       };
-
       style = {
         name = lib.mkOption {
           type = with lib.types; nullOr str;
@@ -149,6 +179,7 @@ in {
           description = ''
             Theme package to be used in Qt5/Qt6 applications.
             Auto-detected from {option}`qt.style.name` if possible.
+            See its documentation for available options.
           '';
         };
       };
@@ -156,11 +187,29 @@ in {
   };
 
   config = let
+    warnGnomeDeprecation = option: name:
+      lib.warnIf (name == "gnome")
+      "The value `gnome` for option `${option}` is deprecated. Use `adwaita` instead."
+      name;
+
+    platformTheme = if (builtins.isString cfg.platformTheme) then {
+      name = lib.warn
+        "The option `qt.platformTheme` has been renamed to `qt.platformTheme.name`."
+        (warnGnomeDeprecation "qt.platformTheme" cfg.platformTheme);
+      package = null;
+    } else if cfg.platformTheme == null then {
+      name = null;
+      package = null;
+    } else {
+      name =
+        warnGnomeDeprecation "cfg.platformTheme.name" cfg.platformTheme.name;
+      package = cfg.platformTheme.package;
+    };
 
     # Necessary because home.sessionVariables doesn't support mkIf
     envVars = lib.filterAttrs (n: v: v != null) {
-      QT_QPA_PLATFORMTHEME = if (cfg.platformTheme != null) then
-        styleNames.${cfg.platformTheme} or cfg.platformTheme
+      QT_QPA_PLATFORMTHEME = if (platformTheme.name != null) then
+        styleNames.${platformTheme.name} or platformTheme.name
       else
         null;
       QT_STYLE_OVERRIDE = cfg.style.name;
@@ -181,10 +230,10 @@ in {
 
   in lib.mkIf cfg.enable {
     assertions = [{
-      assertion = cfg.platformTheme == "gnome" -> cfg.style.name != null
+      assertion = platformTheme.name == "gnome" -> cfg.style.name != null
         && cfg.style.package != null;
       message = ''
-        `qt.platformTheme` "gnome" must have `qt.style` set to a theme that
+        `qt.platformTheme.name` "gnome" must have `qt.style` set to a theme that
         supports both Qt and Gtk, for example "adwaita", "adwaita-dark", or "breeze".
       '';
     }];
@@ -208,13 +257,16 @@ in {
     # Apply theming also to apps started by systemd.
     systemd.user.sessionVariables = envVars // envVarsExtra;
 
-    home.packages = (lib.optionals (cfg.platformTheme != null)
-      platformPackages.${cfg.platformTheme} or [ ])
-      ++ (lib.optionals (cfg.style.package != null)
-        (lib.toList cfg.style.package));
+    home.packages = (lib.findFirst (x: x != null) [ ] [
+      (lib.optionals (platformTheme.package != null)
+        (lib.toList platformTheme.package))
+      (lib.optionals (platformTheme.name != null)
+        platformPackages.${platformTheme.name})
+    ]) ++ (lib.optionals (cfg.style.package != null)
+      (lib.toList cfg.style.package));
 
     xsession.importedVariables = [ "QT_PLUGIN_PATH" "QML2_IMPORT_PATH" ]
-      ++ lib.optionals (cfg.platformTheme != null) [ "QT_QPA_PLATFORMTHEME" ]
+      ++ lib.optionals (platformTheme.name != null) [ "QT_QPA_PLATFORMTHEME" ]
       ++ lib.optionals (cfg.style.name != null) [ "QT_STYLE_OVERRIDE" ];
   };
 }
diff --git a/tests/modules/misc/qt/qt-basic.nix b/tests/modules/misc/qt/qt-basic.nix
index 9ddddb35..a4cadcb7 100644
--- a/tests/modules/misc/qt/qt-basic.nix
+++ b/tests/modules/misc/qt/qt-basic.nix
@@ -1,5 +1,3 @@
-{ config, lib, pkgs, ... }:
-
 {
   config = {
     qt.enable = true;
diff --git a/tests/modules/misc/qt/qt-platform-theme-gnome.nix b/tests/modules/misc/qt/qt-platform-theme-gnome.nix
index d95ef704..617d99b0 100644
--- a/tests/modules/misc/qt/qt-platform-theme-gnome.nix
+++ b/tests/modules/misc/qt/qt-platform-theme-gnome.nix
@@ -1,9 +1,8 @@
-{ config, lib, pkgs, ... }:
-
 {
   config = {
     qt = {
       enable = true;
+      # Check if still backwards compatible
       platformTheme = "gnome";
       style.name = "adwaita";
     };
diff --git a/tests/modules/misc/qt/qt-platform-theme-gtk.nix b/tests/modules/misc/qt/qt-platform-theme-gtk.nix
index 070c8020..76a6512f 100644
--- a/tests/modules/misc/qt/qt-platform-theme-gtk.nix
+++ b/tests/modules/misc/qt/qt-platform-theme-gtk.nix
@@ -1,10 +1,8 @@
-{ config, lib, pkgs, ... }:
-
 {
   config = {
     qt = {
       enable = true;
-      platformTheme = "gtk";
+      platformTheme.name = "gtk";
     };
     i18n.inputMethod.enabled = "fcitx5";
 
diff --git a/tests/modules/misc/qt/qt-platform-theme-gtk3.nix b/tests/modules/misc/qt/qt-platform-theme-gtk3.nix
index 2b3ade9d..26408818 100644
--- a/tests/modules/misc/qt/qt-platform-theme-gtk3.nix
+++ b/tests/modules/misc/qt/qt-platform-theme-gtk3.nix
@@ -1,10 +1,8 @@
-{ config, lib, pkgs, ... }:
-
 {
   config = {
     qt = {
       enable = true;
-      platformTheme = "gtk3";
+      platformTheme.name = "gtk3";
     };
 
     nmt.script = ''