9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
78 lines
1.9 KiB
Nix
78 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
stubType = types.submodule ({ name, ... }: {
|
|
options = {
|
|
name = mkOption {
|
|
type = types.str;
|
|
default = "dummy";
|
|
description = "The stub package name.";
|
|
};
|
|
|
|
outPath = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = "@${name}@";
|
|
defaultText = literalExpression ''"@''${name}@"'';
|
|
};
|
|
|
|
version = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = null;
|
|
defaultText = literalExpression "pkgs.\${name}.version or null";
|
|
};
|
|
|
|
buildScript = mkOption {
|
|
type = types.str;
|
|
default = defaultBuildScript;
|
|
};
|
|
};
|
|
});
|
|
|
|
defaultBuildScript = "mkdir $out";
|
|
|
|
dummyPackage = pkgs.runCommandLocal "dummy" { } defaultBuildScript;
|
|
|
|
mkStubPackage = { name ? "dummy", outPath ? null, version ? null
|
|
, buildScript ? defaultBuildScript }:
|
|
let
|
|
pkg = if name == "dummy" && buildScript == defaultBuildScript then
|
|
dummyPackage
|
|
else
|
|
pkgs.runCommandLocal name { pname = name; } buildScript;
|
|
in pkg // optionalAttrs (outPath != null) {
|
|
inherit outPath;
|
|
|
|
# Prevent getOutput from descending into outputs
|
|
outputSpecified = true;
|
|
|
|
# Allow the original package to be used in derivation inputs
|
|
__spliced = {
|
|
buildHost = pkg;
|
|
hostTarget = pkg;
|
|
};
|
|
} // optionalAttrs (version != null) { inherit version; };
|
|
|
|
in {
|
|
options.test.stubs = mkOption {
|
|
type = types.attrsOf stubType;
|
|
default = { };
|
|
description =
|
|
"Package attributes that should be replaced by a stub package.";
|
|
};
|
|
|
|
config = {
|
|
lib.test.mkStubPackage = mkStubPackage;
|
|
|
|
nixpkgs.overlays = mkIf (config.test.stubs != { }) [
|
|
(self: super:
|
|
mapAttrs (n: v:
|
|
mkStubPackage (v // optionalAttrs (v.version == null) {
|
|
version = super.${n}.version or null;
|
|
})) config.test.stubs)
|
|
];
|
|
};
|
|
}
|